BUILD.gn

# Copyright (c) 2013-2019 Huawei Technologies Co., Ltd. All rights reserved.
# Copyright (c) 2020-2021 Huawei Device Co., Ltd. All rights reserved.
#
# Redistribution and use in source and binary forms, with or without modification,
# are permitted provided that the following conditions are met:
#
# 1. Redistributions of source code must retain the above copyright notice, this list of
#    conditions and the following disclaimer.
#
# 2. Redistributions in binary form must reproduce the above copyright notice, this list
#    of conditions and the following disclaimer in the documentation and/or other materials
#    provided with the distribution.
#
# 3. Neither the name of the copyright holder nor the names of its contributors may be used
#    to endorse or promote products derived from this software without specific prior written
#    permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
# THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR
# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
# EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
# OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
# WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
# OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

import("//kernel/liteos_a/liteos.gni")

module_name = "bsp"
kernel_module(module_name) {
  sources = [ "main.c" ]

  sources += [
    "hwi_shell.c",
    "los_cir_buf.c",
    "los_config.c",
    "los_excinfo.c",
    "los_init.c",
    "los_magickey.c",
    "los_printf.c",
    "los_seq_buf.c",
  ]

  if (defined(LOSCFG_FS_VFS)) {
    sources += [
      "console.c",
      "virtual_serial.c",
    ]
  }

  if (defined(LOSCFG_BASE_CORE_HILOG)) {
    sources += [ "los_hilog.c" ]
  }

  public_configs = [ ":public" ]
}

group("platform") {
  public_deps = [ ":$module_name" ]
}

config("public") {
  include_dirs = [ "." ]
}

source_set("board") {
  sources = [ "board.ld.S" ]

  configs = []
  configs += [
    "$LITEOSTOPDIR:los_config",
    "$LITEOSTOPDIR:public",
  ]

  asmflags = [
    "-P",
    "-E",
  ]
}

copy("board.ld") {
  deps = [ ":board" ]
  sources = [ "$target_out_dir/board.board.ld.o" ]
  outputs = [ "$root_out_dir/board.ld" ]
}