BUILD.gn

# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

root_dist_dir = "$root_build_dir/dist"

copy("sky_viewer") {
  sources = [
    "$root_build_dir/sky_viewer.mojo",
  ]
  outputs = [ "$root_dist_dir/viewer/{{source_file_part}}" ]

  deps = [
    "//services/sky",
  ]
}

copy("sky_shell") {
  if (is_android) {
    sources = [
      "$root_build_dir/apks/SkyShell.apk",
    ]

    deps = [
      "//sky/shell",
    ]
  } else if (is_ios || is_mac) {
    sources = [
      "$root_build_dir/Sky.app",
    ]

    deps = [
      "//sky/shell:shell_struct",
    ]
  } else {
    sources = [
      "$root_build_dir/sky_shell",
      "$root_build_dir/icudtl.dat",
    ]

    deps = [
      "//sky/shell",
      "//third_party/icu:icudata",
    ]
  }

  outputs = [ "$root_dist_dir/shell/{{source_file_part}}" ]
}

if (is_android) {
  import("//build/config/android/rules.gni")

  sky_engine_package_dir = "$root_dist_dir/packages/sky_engine"

  copy_ex("copy_sky_engine_package") {
    clear_dir = true
    dest = "$root_dist_dir/packages"
    sources = [
      "$root_gen_dir/dart-pkg/sky_engine",
    ]
    deps = [
      "//sky/packages/sky_engine",
    ]
  }

  copy("copy_sky_engine_license") {
    sources = [
      "//AUTHORS",
      "//LICENSE",
    ]
    outputs = [ "$sky_engine_package_dir/{{source_file_part}}" ]
    deps = [
      ":copy_sky_engine_package"
    ]
  }

  copy("copy_sky_engine_apks") {
    sources = [
      "$root_dist_dir/shell/SkyShell.apk",
    ]
    outputs = [ "$sky_engine_package_dir/apks/{{source_file_part}}" ]
    deps = [
      ":copy_sky_engine_package",
      ":sky_shell",
    ]
  }

  group("sky_engine") {
    deps = [
      ":copy_sky_engine_package",
      ":copy_sky_engine_license",
      ":copy_sky_engine_apks",
    ]
  }
}

group("dist") {
  deps = [
    ":sky_viewer",
  ]

  if (!is_ios && !is_mac) {
    deps += [ ":sky_shell" ]
  }

  if (is_android) {
    deps += [ ":sky_engine" ]
  }
}