balance_replica1.sim

system sh/stop_dnodes.sh

system sh/ip.sh -i 1 -s up
system sh/ip.sh -i 2 -s up
system sh/deploy.sh -n dnode1 -m 192.168.0.1 -i 192.168.0.1
system sh/deploy.sh -n dnode2 -m 192.168.0.1 -i 192.168.0.2
system sh/cfg.sh -n dnode1 -c numOfTotalVnodes -v 4
system sh/cfg.sh -n dnode2 -c numOfTotalVnodes -v 4
system sh/cfg.sh -n dnode1 -c statusInterval -v 1
system sh/cfg.sh -n dnode2 -c statusInterval -v 1
system sh/cfg.sh -n dnode1 -c balanceMonitorInterval -v 1
system sh/cfg.sh -n dnode2 -c balanceMonitorInterval -v 1
system sh/cfg.sh -n dnode1 -c balanceStartInterval -v 10
system sh/cfg.sh -n dnode2 -c balanceStartInterval -v 10
system sh/cfg.sh -n dnode1 -c commitLog -v 0
system sh/cfg.sh -n dnode2 -c commitLog -v 0
system sh/cfg.sh -n dnode1 -c mgmtEqualVnodeNum -v 0
system sh/cfg.sh -n dnode2 -c mgmtEqualVnodeNum -v 0
system sh/cfg.sh -n dnode1 -c sessionsPerVnode -v 4
system sh/cfg.sh -n dnode2 -c sessionsPerVnode -v 4

$dbPrefix = br1_db
$tbPrefix = br1_tb
$mtPrefix = br1_mt
$tbNum = 13
$rowNum = 200
$totalNum = 200

print ============== step1
print ========= start dnode1
system sh/exec.sh -n dnode1 -s start
sql connect

$i = 0
$db = $dbPrefix
$mt = $mtPrefix
$st = $stPrefix . $i

sql create database $db tables 4
sql use $db
sql create table $mt (ts timestamp, tbcol int, tbcol2 float) TAGS(tgcol int)

$i = 0
while $i < $tbNum
  $tb = $tbPrefix . $i
  sql create table $tb using $mt tags( $i )
  
  $x = 0
  $y = 0
  while $y < $rowNum
    $val = $x * 60000
    $ms = 1519833600000 + $val 
    sql insert into $tb values ($ms , $y , $y ) 
    $x = $x + 1
    $y = $y + 1
  endw 
 
  $i = $i + 1
endw 

sleep 100

print =============== step2

$x = 0
show1: 
	$x = $x + 1
	sleep 1000
	if $x == 20 then 
	  return -1
	endi
sql show dnodes -x show1
$dnode1Vnodes = $data3_192.168.0.1
print 192.168.0.1 $dnode1Vnodes
$dnode2Vnodes = $data3_192.168.0.2
print 192.168.0.2 $dnode2Vnodes

if $dnode1Vnodes != 0 then
  goto show1
endi
if $dnode2Vnodes != null then
  goto show1
endi
print =============== step3 start dnode2
sql create dnode 192.168.0.2
system sh/exec.sh -n dnode2 -s start
sleep 8000

$x = 0
show2: 
	$x = $x + 1
	sleep 2000
	if $x == 10 then 
	  return -1
	endi
sql show dnodes -x show2
$dnode1Vnodes = $data3_192.168.0.1
print 192.168.0.1 $dnode1Vnodes
$dnode2Vnodes = $data3_192.168.0.2
print 192.168.0.2 $dnode2Vnodes

if $dnode1Vnodes != 2 then
  goto show2
endi
if $dnode2Vnodes != 2 then
  goto show2
endi


print =============== step4
$i = 1
$tb = $tbPrefix . $i
sql select * from $tb
print select * from $tb ==> $rows
if $rows != 200 then
  return -1
endi

$i = 5
$tb = $tbPrefix . $i
sql select * from $tb
print select * from $tb ==> $rows
if $rows != 200 then
  return -1
endi

$i = 8
$tb = $tbPrefix . $i
$st = $stPrefix . $i
sql select * from $tb
print select * from $tb ==> $rows
if $rows != 200 then
  return -1
endi

print =============== step5
sql select * from $mt
print select * from $mt ==> $rows
if $rows != 2600 then
  return -1
endi