BUILD.gn

# Copyright (c) 2020-2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/lite/config/subsystem/aafwk/config.gni")
import("//build/lite/config/test.gni")
import("//test/xts/tools/lite/build/suite_lite.gni")

lite_component("acts_component") {
  all_features = []
  features = []
  if (ohos_xts_test_args != "") {
    args = [
      "--method_name",
      "get_target_modules",
      "--arguments",
      "all_features=${ohos_xts_test_args}",
    ]
    all_features +=
        exec_script(rebase_path("//test/xts/tools/lite/build/utils.py"),
                    args,
                    "list lines")
  } else {
    if (ohos_kernel_type == "liteos_m") {
      all_features += [
        "//test/xts/acts/ability_lite/ability_hal:ActsAbilityMgrTest",
        "//test/xts/acts/appexecfwk_lite/appexecfwk_hal:ActsBundleMgrTest",
        "//test/xts/acts/communication_lite/lwip_hal:ActsLwipTest",

        #"//test/xts/acts/communication_lite/wifiservice_hal:ActsWifiServiceTest",
        "//test/xts/acts/commonlibrary_lite/file_hal:ActsUtilsFileTest",
        "//test/xts/acts/startup_lite/syspara_hal:ActsParameterTest",
        "//test/xts/acts/iothardware_lite/peripheral_hal:ActsWifiIotTest",
        "//test/xts/acts/distributeddatamgr_lite/kv_store_hal:ActsKvStoreTest",
        "//test/xts/acts/security_lite/huks/liteos_m_adapter:ActsHuksHalFunctionTest",
        "//test/xts/acts/hiviewdfx_lite/hilog_hal:ActsDfxFuncTest",
        "//test/xts/acts/hiviewdfx_lite/hievent_hal:ActsHieventLiteTest",
        "//test/xts/acts/distributed_schedule_lite/system_ability_manager_hal:ActsSamgrTest",
        "//test/xts/acts/update_lite/dupdate_hal:ActsUpdaterFuncTest",
        "//test/xts/acts/startup_lite/bootstrap_hal:ActsBootstrapTest",
        "//test/xts/acts/xts_lite/device_attest_lite/device_attestStart_hal:ActsDeviceAttestTest",
      ]
    } else if (ohos_kernel_type == "uniproton") {
      all_features += [
        "//test/xts/acts/commonlibrary_lite/file_hal:ActsUtilsFileTest",
        "//test/xts/acts/startup_lite/bootstrap_hal:ActsBootstrapTest",
      ]
      features += [ "//test/xts/acts/communication_lite/lwip_hal:ActsLwipTest" ]
    } else if (ohos_kernel_type == "liteos_a") {
      all_features += [
        "//test/xts/acts/kernel_lite:ActsKernelTest",
        "//test/xts/acts/security_lite:securitytest",
        "//test/xts/acts/distributeddatamgr_lite/kv_store_posix:ActsKvStoreTest",
        "//test/xts/acts/startup_lite/syspara_posix:ActsParameterTest",
        "//test/xts/acts/startup_lite/bootstrap_posix:ActsBootstrapTest",
        "//test/xts/acts/open_posix_testsuite/conformance/interfaces:ActsOpenPosixTest",

        "//test/xts/acts/multimedia_lite/camera_lite_posix/camera_native:ActsMediaCameraTest",
        "//test/xts/acts/multimedia_lite/media_lite_posix/player_native:ActsMediaPlayerTest",
        "//test/xts/acts/multimedia_lite/media_lite_posix/recorder_native:ActsMediaRecorderTest",
        "//test/xts/acts/multimedia_lite/media_lite_posix/audio_native:ActsMediaAudioTest",

        "//test/xts/acts/distributed_schedule_lite/system_ability_manager_posix:ActsSamgrTest",

        #"//test/xts/acts/systemabilitymgr_lite/distributed_schedule_posix:ActsDMSTest",
        "//test/xts/acts/hiviewdfx_lite/hilog_posix:ActsHilogTest",

        "//test/xts/acts/appexecfwk_lite/appexecfwk_posix:ActsBundleMgrTest",
        "//test/xts/acts/ability_lite/ability_posix:ActsAbilityMgrTest",
        "//test/xts/acts/communication_lite/lwip_posix:ActsLwipTest",

        "//test/xts/acts/ai_lite/ai_engine_posix/base:ActsAiEngineTest",
        "//test/xts/acts/global_lite:ActsGlobalTest",
        "//test/xts/acts/sensors_lite:sensorstest",
        "//test/xts/acts/update_lite/dupdate_posix:ActsUpdateTest",
        "//test/xts/acts/xts_lite/device_attest_lite/device_attestStart_posix:ActsDeviceAttestStartTest",
        "//test/xts/acts/xts_lite/device_attest_lite/device_attestQuerry_posix:ActsDeviceAttestQuerryTest",
      ]
    } else if (ohos_kernel_type == "linux") {
      all_features += [
        "//test/xts/acts/distributeddatamgr_lite/kv_store_posix:ActsKvStoreTest",
        "//test/xts/acts/startup_lite/syspara_posix:ActsParameterTest",
        "//test/xts/acts/startup_lite/bootstrap_posix:ActsBootstrapTest",
        "//test/xts/acts/communication_lite/lwip_posix:ActsLwipTest",
        "//test/xts/acts/security_lite:securitytest",

        #"//test/xts/acts/multimedia_lite/camera_lite_posix/camera_native:ActsMediaCameraTest",
        #"//test/xts/acts/multimedia_lite/media_lite_posix/player_native:ActsMediaPlayerTest",
        #"//test/xts/acts/multimedia_lite/media_lite_posix/recorder_native:ActsMediaRecorderTest",
        "//test/xts/acts/distributed_schedule_lite/system_ability_manager_posix:ActsSamgrTest",
        "//test/xts/acts/appexecfwk_lite/appexecfwk_posix:ActsBundleMgrTest",
        "//test/xts/acts/ability_lite/ability_posix:ActsAbilityMgrTest",
        "//test/xts/acts/ai_lite/ai_engine_posix/base:ActsAiEngineTest",
        "//test/xts/acts/xts_lite/device_attest_lite/device_attestStart_posix:ActsDeviceAttestStartTest",
        "//test/xts/acts/xts_lite/device_attest_lite/device_attestQuerry_posix:ActsDeviceAttestQuerryTest",
      ]
    }
  }

  if (ohos_build_type == "debug" && ohos_test_args != "notest") {
    _all_features = ""
    _product_json = rebase_path("${product_config_path}/config.json")
    foreach(one_feature, all_features) {
      _all_features = _all_features + one_feature + ","
    }
    _args = [
      "--method_name",
      "filter_by_subsystem",
      "--arguments",
      "testsuites=${_all_features}#product_json=${_product_json}",
    ]
    features += exec_script(rebase_path("//test/xts/tools/lite/build/utils.py"),
                            _args,
                            "list lines")
  }
}

test_suite("acts") {
  deps = [ ":acts_component" ]
  version = "OpenHarmony-ACTS-1.0.1"
  if (ohos_kernel_type == "liteos_a") {
    deps += [ "//test/xts/tools/lite/others/query:query" ]
    copy("query_copy") {
      sources = [ "$root_out_dir/bin/query.bin" ]
      outputs = [ "$root_out_dir/suites/acts/resource/tools/query.bin" ]
    }
  }
}

generate_notice_file("acts_notice_file") {
  module_name = "acts"
  module_source_dir_list = [
    "//third_party/googletest",
    "//third_party/unity",
    "//third_party/bounds_checking_function",
  ]
}