BUILD.gn

# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")

config("inithook_config") {
  include_dirs = [ "//base/startup/init/services/modules/init_hook" ]
}
comm_include = [
  "//base/startup/init/services/include",
  "//base/startup/init/services/include/param",
  "//base/startup/init/services/modules",
  "//base/startup/init/services/modules/init_hook",
  "//base/startup/init/services/init/include",
  "//base/startup/init/services/loopevent/include",
  "//base/startup/init/services/log",
  "//base/startup/init/interfaces/innerkits/include",
  "//third_party/cJSON",
  "//third_party/bounds_checking_function/include",
]
if (defined(ohos_lite)) {
  static_library("inithook") {
    defines = [
      "_GNU_SOURCE",
      "OHOS_LITE",
    ]
    include_dirs = comm_include
    sources = [ "param_hook.c" ]
    public_configs = [ ":inithook_config" ]
  }
} else {
  ohos_source_set("inithook") {
    defines = [
      "_GNU_SOURCE",
      "PARAM_SUPPORT_TRIGGER",
    ]
    include_dirs = comm_include
    sources = [
      "init_hook.c",
      "param_hook.c",
    ]
    if (build_selinux) {
      include_dirs += [
        "//third_party/selinux/libselinux/include/",
        "//base/security/selinux/interfaces/policycoreutils/include/",
      ]
      defines += [ "WITH_SELINUX" ]
    }
    public_configs = [ ":inithook_config" ]
    public_configs += [ "//base/startup/init/interfaces/innerkits/init_module_engine:init_module_engine_exported_config" ]
  }
}