proc-v7.S 13.4 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11
/*
 *  linux/arch/arm/mm/proc-v7.S
 *
 *  Copyright (C) 2001 Deep Blue Solutions Ltd.
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 *
 *  This is the "shell" of the ARMv7 processor support.
 */
12
#include <linux/init.h>
13 14 15
#include <linux/linkage.h>
#include <asm/assembler.h>
#include <asm/asm-offsets.h>
16
#include <asm/hwcap.h>
17 18 19 20 21 22
#include <asm/pgtable-hwdef.h>
#include <asm/pgtable.h>

#include "proc-macros.S"

#define TTB_S		(1 << 1)
23 24
#define TTB_RGN_NC	(0 << 3)
#define TTB_RGN_OC_WBWA	(1 << 3)
25 26
#define TTB_RGN_OC_WT	(2 << 3)
#define TTB_RGN_OC_WB	(3 << 3)
27 28 29 30 31
#define TTB_NOS		(1 << 5)
#define TTB_IRGN_NC	((0 << 0) | (0 << 6))
#define TTB_IRGN_WBWA	((0 << 0) | (1 << 6))
#define TTB_IRGN_WT	((1 << 0) | (0 << 6))
#define TTB_IRGN_WB	((1 << 0) | (1 << 6))
32

33
/* PTWs cacheable, inner WB not shareable, outer WB not shareable */
34 35 36
#define TTB_FLAGS_UP	TTB_IRGN_WB|TTB_RGN_OC_WB
#define PMD_FLAGS_UP	PMD_SECT_WB

37
/* PTWs cacheable, inner WBWA shareable, outer WBWA not shareable */
38 39
#define TTB_FLAGS_SMP	TTB_IRGN_WBWA|TTB_S|TTB_NOS|TTB_RGN_OC_WBWA
#define PMD_FLAGS_SMP	PMD_SECT_WBWA|PMD_SECT_S
40

41 42
ENTRY(cpu_v7_proc_init)
	mov	pc, lr
43
ENDPROC(cpu_v7_proc_init)
44 45

ENTRY(cpu_v7_proc_fin)
46 47 48 49
	mrc	p15, 0, r0, c1, c0, 0		@ ctrl register
	bic	r0, r0, #0x1000			@ ...i............
	bic	r0, r0, #0x0006			@ .............ca.
	mcr	p15, 0, r0, c1, c0, 0		@ disable caches
50
	mov	pc, lr
51
ENDPROC(cpu_v7_proc_fin)
52 53 54 55 56 57 58 59 60

/*
 *	cpu_v7_reset(loc)
 *
 *	Perform a soft reset of the system.  Put the CPU into the
 *	same state as it would be if it had been reset, and branch
 *	to what would be the reset vector.
 *
 *	- loc   - location to jump to for soft reset
61 62 63
 *
 *	This code must be executed using a flat identity mapping with
 *      caches disabled.
64 65 66
 */
	.align	5
ENTRY(cpu_v7_reset)
67 68
	mrc	p15, 0, r1, c1, c0, 0		@ ctrl register
	bic	r1, r1, #0x1			@ ...............m
69
 THUMB(	bic	r1, r1, #1 << 30 )		@ SCTLR.TE (Thumb exceptions)
70 71
	mcr	p15, 0, r1, c1, c0, 0		@ disable MMU
	isb
72
	mov	pc, r0
73
ENDPROC(cpu_v7_reset)
74 75 76 77 78 79 80 81 82

/*
 *	cpu_v7_do_idle()
 *
 *	Idle the processor (eg, wait for interrupt).
 *
 *	IRQs are already disabled.
 */
ENTRY(cpu_v7_do_idle)
83
	dsb					@ WFI may enter a low-power mode
84
	wfi
85
	mov	pc, lr
86
ENDPROC(cpu_v7_do_idle)
87 88 89 90 91 92 93 94 95 96 97

ENTRY(cpu_v7_dcache_clean_area)
#ifndef TLB_CAN_READ_FROM_L1_CACHE
	dcache_line_size r2, r3
1:	mcr	p15, 0, r0, c7, c10, 1		@ clean D entry
	add	r0, r0, r2
	subs	r1, r1, r2
	bhi	1b
	dsb
#endif
	mov	pc, lr
98
ENDPROC(cpu_v7_dcache_clean_area)
99 100 101 102 103 104 105 106 107 108 109 110

/*
 *	cpu_v7_switch_mm(pgd_phys, tsk)
 *
 *	Set the translation table base pointer to be pgd_phys
 *
 *	- pgd_phys - physical address of new TTB
 *
 *	It is assumed that:
 *	- we are not using split page tables
 */
ENTRY(cpu_v7_switch_mm)
111
#ifdef CONFIG_MMU
112 113
	mov	r2, #0
	ldr	r1, [r1, #MM_CONTEXT_ID]	@ get mm->context.id
114 115
	ALT_SMP(orr	r0, r0, #TTB_FLAGS_SMP)
	ALT_UP(orr	r0, r0, #TTB_FLAGS_UP)
116 117
#ifdef CONFIG_ARM_ERRATA_430973
	mcr	p15, 0, r2, c7, c5, 6		@ flush BTAC/BTB
118
#endif
119 120 121 122 123 124
#ifdef CONFIG_ARM_ERRATA_754322
	dsb
#endif
	mcr	p15, 0, r2, c13, c0, 1		@ set reserved context ID
	isb
1:	mcr	p15, 0, r0, c2, c0, 0		@ set TTB 0
125
	isb
126 127 128
#ifdef CONFIG_ARM_ERRATA_754322
	dsb
#endif
129 130
	mcr	p15, 0, r1, c13, c0, 1		@ set context ID
	isb
131
#endif
132
	mov	pc, lr
133
ENDPROC(cpu_v7_switch_mm)
134 135 136 137 138 139 140

/*
 *	cpu_v7_set_pte_ext(ptep, pte)
 *
 *	Set a level 2 translation table entry.
 *
 *	- ptep  - pointer to level 2 translation table entry
141
 *		  (hardware version is stored at +2048 bytes)
142 143 144 145
 *	- pte   - PTE value to store
 *	- ext	- value for extended PTE bits
 */
ENTRY(cpu_v7_set_pte_ext)
146
#ifdef CONFIG_MMU
147
	str	r1, [r0]			@ linux version
148 149

	bic	r3, r1, #0x000003f0
150
	bic	r3, r3, #PTE_TYPE_MASK
151 152 153
	orr	r3, r3, r2
	orr	r3, r3, #PTE_EXT_AP0 | 2

154
	tst	r1, #1 << 4
155 156
	orrne	r3, r3, #PTE_EXT_TEX(1)

157 158 159
	eor	r1, r1, #L_PTE_DIRTY
	tst	r1, #L_PTE_RDONLY | L_PTE_DIRTY
	orrne	r3, r3, #PTE_EXT_APX
160 161 162

	tst	r1, #L_PTE_USER
	orrne	r3, r3, #PTE_EXT_AP1
163 164
#ifdef CONFIG_CPU_USE_DOMAINS
	@ allow kernel read/write access to read-only user pages
165 166
	tstne	r3, #PTE_EXT_APX
	bicne	r3, r3, #PTE_EXT_APX | PTE_EXT_AP0
167
#endif
168

169 170
	tst	r1, #L_PTE_XN
	orrne	r3, r3, #PTE_EXT_XN
171

172 173
	tst	r1, #L_PTE_YOUNG
	tstne	r1, #L_PTE_PRESENT
174 175
	moveq	r3, #0

176 177 178
 ARM(	str	r3, [r0, #2048]! )
 THUMB(	add	r0, r0, #2048 )
 THUMB(	str	r3, [r0] )
179
	mcr	p15, 0, r0, c7, c10, 1		@ flush_pte
180
#endif
181
	mov	pc, lr
182
ENDPROC(cpu_v7_set_pte_ext)
183

184
	string	cpu_v7_name, "ARMv7 Processor"
185 186
	.align

187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219
	/*
	 * Memory region attributes with SCTLR.TRE=1
	 *
	 *   n = TEX[0],C,B
	 *   TR = PRRR[2n+1:2n]		- memory type
	 *   IR = NMRR[2n+1:2n]		- inner cacheable property
	 *   OR = NMRR[2n+17:2n+16]	- outer cacheable property
	 *
	 *			n	TR	IR	OR
	 *   UNCACHED		000	00
	 *   BUFFERABLE		001	10	00	00
	 *   WRITETHROUGH	010	10	10	10
	 *   WRITEBACK		011	10	11	11
	 *   reserved		110
	 *   WRITEALLOC		111	10	01	01
	 *   DEV_SHARED		100	01
	 *   DEV_NONSHARED	100	01
	 *   DEV_WC		001	10
	 *   DEV_CACHED		011	10
	 *
	 * Other attributes:
	 *
	 *   DS0 = PRRR[16] = 0		- device shareable property
	 *   DS1 = PRRR[17] = 1		- device shareable property
	 *   NS0 = PRRR[18] = 0		- normal shareable property
	 *   NS1 = PRRR[19] = 1		- normal shareable property
	 *   NOS = PRRR[24+n] = 1	- not outer shareable
	 */
.equ	PRRR,	0xff0a81a8
.equ	NMRR,	0x40e040e0

/* Suspend/resume support: derived from arch/arm/mach-s5pv210/sleep.S */
.globl	cpu_v7_suspend_size
220
.equ	cpu_v7_suspend_size, 4 * 7
221
#ifdef CONFIG_ARM_CPU_SUSPEND
222
ENTRY(cpu_v7_do_suspend)
223
	stmfd	sp!, {r4 - r10, lr}
224
	mrc	p15, 0, r4, c13, c0, 0	@ FCSE/PID
225 226
	mrc	p15, 0, r5, c13, c0, 3	@ User r/o thread ID
	stmia	r0!, {r4 - r5}
227
	mrc	p15, 0, r6, c3, c0, 0	@ Domain ID
228 229 230 231 232 233
	mrc	p15, 0, r7, c2, c0, 1	@ TTB 1
	mrc	p15, 0, r8, c1, c0, 0	@ Control register
	mrc	p15, 0, r9, c1, c0, 1	@ Auxiliary control register
	mrc	p15, 0, r10, c1, c0, 2	@ Co-processor access control
	stmia	r0, {r6 - r10}
	ldmfd	sp!, {r4 - r10, pc}
234 235 236 237 238 239
ENDPROC(cpu_v7_do_suspend)

ENTRY(cpu_v7_do_resume)
	mov	ip, #0
	mcr	p15, 0, ip, c8, c7, 0	@ invalidate TLBs
	mcr	p15, 0, ip, c7, c5, 0	@ invalidate I cache
240 241
	mcr	p15, 0, ip, c13, c0, 1	@ set reserved context ID
	ldmia	r0!, {r4 - r5}
242
	mcr	p15, 0, r4, c13, c0, 0	@ FCSE/PID
243
	mcr	p15, 0, r5, c13, c0, 3	@ User r/o thread ID
244
	ldmia	r0, {r6 - r10}
245
	mcr	p15, 0, r6, c3, c0, 0	@ Domain ID
246 247 248 249
	ALT_SMP(orr	r1, r1, #TTB_FLAGS_SMP)
	ALT_UP(orr	r1, r1, #TTB_FLAGS_UP)
	mcr	p15, 0, r1, c2, c0, 0	@ TTB 0
	mcr	p15, 0, r7, c2, c0, 1	@ TTB 1
250
	mcr	p15, 0, ip, c2, c0, 2	@ TTB control register
251
	mrc	p15, 0, r4, c1, c0, 1	@ Read Auxiliary control register
252 253 254
	teq	r4, r9			@ Is it already set?
	mcrne	p15, 0, r9, c1, c0, 1	@ No, so write it
	mcr	p15, 0, r10, c1, c0, 2	@ Co-processor access control
255 256 257 258 259
	ldr	r4, =PRRR		@ PRRR
	ldr	r5, =NMRR		@ NMRR
	mcr	p15, 0, r4, c10, c2, 0	@ write PRRR
	mcr	p15, 0, r5, c10, c2, 1	@ write NMRR
	isb
260
	dsb
261
	mov	r0, r8			@ control register
262 263 264 265
	b	cpu_resume_mmu
ENDPROC(cpu_v7_do_resume)
#endif

266
	__CPUINIT
267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282

/*
 *	__v7_setup
 *
 *	Initialise TLB, Caches, and MMU state ready to switch the MMU
 *	on.  Return in r0 the new CP15 C1 control register setting.
 *
 *	We automatically detect if we have a Harvard cache, and use the
 *	Harvard cache control instructions insead of the unified cache
 *	control instructions.
 *
 *	This should be able to cover all ARMv7 cores.
 *
 *	It is assumed that:
 *	- cache type register is implemented
 */
P
Pawel Moll 已提交
283
__v7_ca5mp_setup:
284
__v7_ca9mp_setup:
285 286 287 288 289
	mov	r10, #(1 << 0)			@ TLB ops broadcasting
	b	1f
__v7_ca15mp_setup:
	mov	r10, #0
1:
290
#ifdef CONFIG_SMP
291 292
	ALT_SMP(mrc	p15, 0, r0, c1, c0, 1)
	ALT_UP(mov	r0, #(1 << 6))		@ fake it for UP
293
	tst	r0, #(1 << 6)			@ SMP/nAMP mode enabled?
294 295 296
	orreq	r0, r0, #(1 << 6)		@ Enable SMP/nAMP mode
	orreq	r0, r0, r10			@ Enable CPU-specific SMP bits
	mcreq	p15, 0, r0, c1, c0, 1
297
#endif
298
__v7_setup:
299 300 301 302
	adr	r12, __v7_setup_stack		@ the local stack
	stmia	r12, {r0-r5, r7, r9, r11, lr}
	bl	v7_flush_dcache_all
	ldmia	r12, {r0-r5, r7, r9, r11, lr}
303 304 305 306

	mrc	p15, 0, r0, c0, c0, 0		@ read main ID register
	and	r10, r0, #0xff000000		@ ARM?
	teq	r10, #0x41000000
307
	bne	3f
308 309
	and	r5, r0, #0x00f00000		@ variant
	and	r6, r0, #0x0000000f		@ revision
310 311
	orr	r6, r6, r5, lsr #20-4		@ combine variant and revision
	ubfx	r0, r0, #4, #12			@ primary part number
312

313 314 315 316
	/* Cortex-A8 Errata */
	ldr	r10, =0x00000c08		@ Cortex-A8 primary part number
	teq	r0, r10
	bne	2f
317
#ifdef CONFIG_ARM_ERRATA_430973
318 319 320 321
	teq	r5, #0x00100000			@ only present in r1p*
	mrceq	p15, 0, r10, c1, c0, 1		@ read aux control register
	orreq	r10, r10, #(1 << 6)		@ set IBE to 1
	mcreq	p15, 0, r10, c1, c0, 1		@ write aux control register
322 323
#endif
#ifdef CONFIG_ARM_ERRATA_458693
324
	teq	r6, #0x20			@ only present in r2p0
325 326 327 328
	mrceq	p15, 0, r10, c1, c0, 1		@ read aux control register
	orreq	r10, r10, #(1 << 5)		@ set L1NEON to 1
	orreq	r10, r10, #(1 << 9)		@ set PLDNOP to 1
	mcreq	p15, 0, r10, c1, c0, 1		@ write aux control register
329 330
#endif
#ifdef CONFIG_ARM_ERRATA_460075
331
	teq	r6, #0x20			@ only present in r2p0
332 333 334 335
	mrceq	p15, 1, r10, c9, c0, 2		@ read L2 cache aux ctrl register
	tsteq	r10, #1 << 22
	orreq	r10, r10, #(1 << 22)		@ set the Write Allocate disable bit
	mcreq	p15, 1, r10, c9, c0, 2		@ write the L2 cache aux ctrl register
336
#endif
337 338 339 340 341 342 343 344 345 346 347 348
	b	3f

	/* Cortex-A9 Errata */
2:	ldr	r10, =0x00000c09		@ Cortex-A9 primary part number
	teq	r0, r10
	bne	3f
#ifdef CONFIG_ARM_ERRATA_742230
	cmp	r6, #0x22			@ only present up to r2p2
	mrcle	p15, 0, r10, c15, c0, 1		@ read diagnostic register
	orrle	r10, r10, #1 << 4		@ set bit #4
	mcrle	p15, 0, r10, c15, c0, 1		@ write diagnostic register
#endif
349 350 351 352 353 354 355 356 357
#ifdef CONFIG_ARM_ERRATA_742231
	teq	r6, #0x20			@ present in r2p0
	teqne	r6, #0x21			@ present in r2p1
	teqne	r6, #0x22			@ present in r2p2
	mrceq	p15, 0, r10, c15, c0, 1		@ read diagnostic register
	orreq	r10, r10, #1 << 12		@ set bit #12
	orreq	r10, r10, #1 << 22		@ set bit #22
	mcreq	p15, 0, r10, c15, c0, 1		@ write diagnostic register
#endif
358 359 360 361 362 363 364 365
#ifdef CONFIG_ARM_ERRATA_743622
	teq	r6, #0x20			@ present in r2p0
	teqne	r6, #0x21			@ present in r2p1
	teqne	r6, #0x22			@ present in r2p2
	mrceq	p15, 0, r10, c15, c0, 1		@ read diagnostic register
	orreq	r10, r10, #1 << 6		@ set bit #6
	mcreq	p15, 0, r10, c15, c0, 1		@ write diagnostic register
#endif
366 367 368 369 370 371
#ifdef CONFIG_ARM_ERRATA_751472
	cmp	r6, #0x30			@ present prior to r3p0
	mrclt	p15, 0, r10, c15, c0, 1		@ read diagnostic register
	orrlt	r10, r10, #1 << 11		@ set bit #11
	mcrlt	p15, 0, r10, c15, c0, 1		@ write diagnostic register
#endif
372

373
3:	mov	r10, #0
374 375 376 377
#ifdef HARVARD_CACHE
	mcr	p15, 0, r10, c7, c5, 0		@ I+BTB cache invalidate
#endif
	dsb
378
#ifdef CONFIG_MMU
379 380
	mcr	p15, 0, r10, c8, c7, 0		@ invalidate I + D TLBs
	mcr	p15, 0, r10, c2, c0, 2		@ TTB control register
381 382
	ALT_SMP(orr	r4, r4, #TTB_FLAGS_SMP)
	ALT_UP(orr	r4, r4, #TTB_FLAGS_UP)
383 384 385
	ALT_SMP(orr	r8, r8, #TTB_FLAGS_SMP)
	ALT_UP(orr	r8, r8, #TTB_FLAGS_UP)
	mcr	p15, 0, r8, c2, c0, 1		@ load TTB1
386 387
	ldr	r5, =PRRR			@ PRRR
	ldr	r6, =NMRR			@ NMRR
388 389
	mcr	p15, 0, r5, c10, c2, 0		@ write PRRR
	mcr	p15, 0, r6, c10, c2, 1		@ write NMRR
390
#endif
391 392
	adr	r5, v7_crval
	ldmia	r5, {r5, r6}
393 394
#ifdef CONFIG_CPU_ENDIAN_BE8
	orr	r6, r6, #1 << 25		@ big-endian page tables
395 396 397 398
#endif
#ifdef CONFIG_SWP_EMULATE
	orr     r5, r5, #(1 << 10)              @ set SW bit in "clear"
	bic     r6, r6, #(1 << 10)              @ clear it in "mmuset"
399
#endif
400 401 402
   	mrc	p15, 0, r0, c1, c0, 0		@ read control register
	bic	r0, r0, r5			@ clear bits them
	orr	r0, r0, r6			@ set them
403
 THUMB(	orr	r0, r0, #1 << 30	)	@ Thumb exceptions
404
	mov	pc, lr				@ return to head.S:__ret
405
ENDPROC(__v7_setup)
406

407
	/*   AT
408 409
	 *  TFR   EV X F   I D LR    S
	 * .EEE ..EE PUI. .T.T 4RVI ZWRS BLDP WCAM
410
	 * rxxx rrxx xxx0 0101 xxxx xxxx x111 xxxx < forced
411
	 *    1    0 110       0011 1100 .111 1101 < we want
412
	 */
413 414
	.type	v7_crval, #object
v7_crval:
415
	crval	clear=0x0120c302, mmuset=0x10c03c7d, ucset=0x00c01c7c
416 417 418 419

__v7_setup_stack:
	.space	4 * 11				@ 11 registers

420 421
	__INITDATA

422 423
	@ define struct processor (see <asm/proc-fns.h> and proc-macros.S)
	define_processor_functions v7, dabort=v7_early_abort, pabort=v7_pabort, suspend=1
424

425 426
	.section ".rodata"

427 428
	string	cpu_arch_name, "armv7"
	string	cpu_elf_name, "v7"
429 430 431 432
	.align

	.section ".proc.info.init", #alloc, #execinstr

433 434 435 436 437 438 439 440 441 442 443
	/*
	 * Standard v7 proc info content
	 */
.macro __v7_proc initfunc, mm_mmuflags = 0, io_mmuflags = 0, hwcaps = 0
	ALT_SMP(.long	PMD_TYPE_SECT | PMD_SECT_AP_WRITE | PMD_SECT_AP_READ | \
			PMD_FLAGS_SMP | \mm_mmuflags)
	ALT_UP(.long	PMD_TYPE_SECT | PMD_SECT_AP_WRITE | PMD_SECT_AP_READ | \
			PMD_FLAGS_UP | \mm_mmuflags)
	.long	PMD_TYPE_SECT | PMD_SECT_XN | PMD_SECT_AP_WRITE | \
		PMD_SECT_AP_READ | \io_mmuflags
	W(b)	\initfunc
444 445
	.long	cpu_arch_name
	.long	cpu_elf_name
446 447
	.long	HWCAP_SWP | HWCAP_HALF | HWCAP_THUMB | HWCAP_FAST_MULT | \
		HWCAP_EDSP | HWCAP_TLS | \hwcaps
448 449 450 451 452
	.long	cpu_v7_name
	.long	v7_processor_functions
	.long	v7wbi_tlb_fns
	.long	v6_user_fns
	.long	v7_cache_fns
453 454
.endm

P
Pawel Moll 已提交
455 456 457 458 459 460 461 462 463 464
	/*
	 * ARM Ltd. Cortex A5 processor.
	 */
	.type   __v7_ca5mp_proc_info, #object
__v7_ca5mp_proc_info:
	.long	0x410fc050
	.long	0xff0ffff0
	__v7_proc __v7_ca5mp_setup
	.size	__v7_ca5mp_proc_info, . - __v7_ca5mp_proc_info

465 466 467 468 469 470 471 472
	/*
	 * ARM Ltd. Cortex A9 processor.
	 */
	.type   __v7_ca9mp_proc_info, #object
__v7_ca9mp_proc_info:
	.long	0x410fc090
	.long	0xff0ffff0
	__v7_proc __v7_ca9mp_setup
473 474
	.size	__v7_ca9mp_proc_info, . - __v7_ca9mp_proc_info

475 476 477 478 479 480 481 482 483 484
	/*
	 * ARM Ltd. Cortex A15 processor.
	 */
	.type	__v7_ca15mp_proc_info, #object
__v7_ca15mp_proc_info:
	.long	0x410fc0f0
	.long	0xff0ffff0
	__v7_proc __v7_ca15mp_setup, hwcaps = HWCAP_IDIV
	.size	__v7_ca15mp_proc_info, . - __v7_ca15mp_proc_info

485 486 487 488 489 490 491
	/*
	 * Match any ARMv7 processor core.
	 */
	.type	__v7_proc_info, #object
__v7_proc_info:
	.long	0x000f0000		@ Required ID value
	.long	0x000f0000		@ Mask for ID
492
	__v7_proc __v7_setup
493
	.size	__v7_proc_info, . - __v7_proc_info