# Copyright (c) 2021-2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
base_sources = [ "init_log.c" ]

config("exported_header_files") {
  visibility = [ ":*" ]
  include_dirs = [
    "//base/startup/init/interfaces/innerkits/include",
    "//base/startup/init/services/log",
    "//base/startup/init/services/include",
  ]
}

if (defined(ohos_lite)) {
  static_library("init_log") {
    sources = base_sources
    defines = [
      "_GNU_SOURCE",
      "OHOS_LITE",
    ]
    public_configs = [ ":exported_header_files" ]

    if (ohos_kernel_type == "linux") {
      defines += [ "INIT_DMESG" ]
    }
    if (ohos_kernel_type == "liteos_m") {
      defines += [ "__LITEOS_M__" ]
    }
    include_dirs = [
      "//base/hiviewdfx/hilog_lite/interfaces/native/kits",
      "//third_party/bounds_checking_function/include",
    ]
  }
} else {
  import("//build/ohos.gni")
  ohos_static_library("init_log") {
    sources = base_sources
    defines = [ "INIT_DMESG" ]
    public_configs = [ ":exported_header_files" ]

    include_dirs = [ "//third_party/bounds_checking_function/include" ]
    part_name = "init"
    subsystem_name = "startup"
  }

  ohos_static_library("agent_log") {
    sources = base_sources
    defines = [ "INIT_AGENT" ]
    public_configs = [ ":exported_header_files" ]
    include_dirs = [ "//third_party/bounds_checking_function/include" ]
    external_deps = [ "hilog:libhilog_base" ]
    part_name = "init"
    subsystem_name = "startup"
  }
}