diff --git a/configure.ac b/configure.ac
index 436a108dc7788650c96ca89df920bfd38bbb6f31..284001abadef73481cc4e4008a83fec91fc5dc81 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1113,25 +1113,8 @@ fi
 AM_CONDITIONAL([WITH_NODE_DEVICES], [test "$with_nodedev" = "yes"])
 
 dnl check if the interface driver should be compiled
-LIBVIRT_ARG_WITH([INTERFACE], [host interface driver], [check])
-
-dnl Don't compile the interface driver without libvirtd
-if test "$with_libvirtd" = "no" ; then
-  with_interface=no
-fi
-
-dnl The interface driver depends on the netcf library or udev library
-case $with_interface:$with_netcf:$with_udev in
-    check:*yes*) with_interface=yes ;;
-    check:no:no) with_interface=no ;;
-    yes:no:no) AC_MSG_ERROR([Requested the Interface driver without netcf or udev support]) ;;
-esac
-
-if test "$with_interface" = "yes" ; then
-  AC_DEFINE_UNQUOTED([WITH_INTERFACE], [1],
-    [whether the interface driver is enabled])
-fi
-AM_CONDITIONAL([WITH_INTERFACE], [test "$with_interface" = "yes"])
+LIBVIRT_DRIVER_ARG_INTERFACE
+LIBVIRT_DRIVER_CHECK_INTERFACE
 
 
 dnl GET_VLAN_VID_CMD is required for virNetDevGetVLanID
@@ -1284,7 +1267,7 @@ LIBVIRT_DRIVER_RESULT_TEST
 LIBVIRT_DRIVER_RESULT_REMOTE
 LIBVIRT_DRIVER_RESULT_NETWORK
 LIBVIRT_DRIVER_RESULT_LIBVIRTD
-AC_MSG_NOTICE([Interface: $with_interface])
+LIBVIRT_DRIVER_RESULT_INTERFACE
 AC_MSG_NOTICE([])
 AC_MSG_NOTICE([Storage Drivers])
 AC_MSG_NOTICE([])
diff --git a/m4/virt-driver-interface.m4 b/m4/virt-driver-interface.m4
new file mode 100644
index 0000000000000000000000000000000000000000..5b385160713aaf45ce7db8e4e2f995f939c1dc90
--- /dev/null
+++ b/m4/virt-driver-interface.m4
@@ -0,0 +1,49 @@
+dnl The interface driver
+dnl
+dnl Copyright (C) 2016 Red Hat, Inc.
+dnl
+dnl This library is free software; you can redistribute it and/or
+dnl modify it under the terms of the GNU Lesser General Public
+dnl License as published by the Free Software Foundation; either
+dnl version 2.1 of the License, or (at your option) any later version.
+dnl
+dnl This library is distributed in the hope that it will be useful,
+dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+dnl Lesser General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU Lesser General Public
+dnl License along with this library.  If not, see
+dnl <http://www.gnu.org/licenses/>.
+dnl
+
+AC_DEFUN([LIBVIRT_DRIVER_ARG_INTERFACE], [
+  LIBVIRT_ARG_WITH([INTERFACE], [host interface driver], [check])
+])
+
+AC_DEFUN([LIBVIRT_DRIVER_CHECK_INTERFACE], [
+  AC_REQUIRE([LIBVIRT_DRIVER_CHECK_LIBVIRTD])
+  AC_REQUIRE([LIBVIRT_CHECK_NETCF])
+  AC_REQUIRE([LIBVIRT_CHECK_UDEV])
+
+  dnl Don't compile the interface driver without libvirtd
+  if test "$with_libvirtd" = "no" ; then
+    with_interface=no
+  fi
+
+  dnl The interface driver depends on the netcf library or udev library
+  case $with_interface:$with_netcf:$with_udev in
+    check:*yes*) with_interface=yes ;;
+    check:no:no) with_interface=no ;;
+    yes:no:no) AC_MSG_ERROR([Requested the Interface driver without netcf or udev support]) ;;
+  esac
+
+  if test "$with_interface" = "yes" ; then
+    AC_DEFINE_UNQUOTED([WITH_INTERFACE], [1], [whether the interface driver is enabled])
+  fi
+  AM_CONDITIONAL([WITH_INTERFACE], [test "$with_interface" = "yes"])
+])
+
+AC_DEFUN([LIBVIRT_DRIVER_RESULT_INTERFACE], [
+  LIBVIRT_RESULT([Interface], [$with_interface])
+])