alpha: beautify vmlinux.lds

Introduced a consistent style in vmlinux.lds and it now matches the
soon-to-be common style for all arch's vmlinux.lds files.

In addition:
- Replaced hardcoded constant with PAGE_SIZE
- Fix page.h so PAGE_SIZE can be used from assembler and in lds files
- Move a few labels inside brackets so linker alignment will not
  make label point ot a too low address
- Replaced DWARF and STABS sections with definitions from asm-generic
Signed-off-by: NSam Ravnborg <sam@ravnborg.org>
Cc: Ivan Kokshaysky <ink@jurassic.park.msu.ru>
Cc: Richard Henderson <rth@twiddle.net>
Signed-off-by: NAndrew Morton <akpm@linux-foundation.org>
Signed-off-by: NLinus Torvalds <torvalds@linux-foundation.org>

arch/alpha/kernel/vmlinux.lds.S

 #include <asm-generic/vmlinux.lds.h>
+#include <asm/page.h>
 
 OUTPUT_FORMAT("elf64-alpha")
 OUTPUT_ARCH(alpha)
@@ -24,43 +25,55 @@ SECTIONS
 	} :kernel
 	_etext = .;	/* End of text section */
 
+	/* Exception table */
 	. = ALIGN(16);
-  __start___ex_table = .;			/* Exception table */
-  __ex_table : { *(__ex_table) }
+	__ex_table : {
+		__start___ex_table = .;
+		*(__ex_table)
 		__stop___ex_table = .;
+	}
 
 	NOTES :kernel :note
-  .dummy : { *(.dummy) } :kernel
+	.dummy : {
+		*(.dummy)
+	} :kernel
 
 	RODATA
 
 	/* Will be freed after init */
-  . = ALIGN(8192);				/* Init code and data */
+	. = ALIGN(PAGE_SIZE);
+	/* Init code and data */
 	__init_begin = .;
 	.init.text : {
 		_sinittext = .;
 		*(.init.text)
 		_einittext = .;
 	}
-  .init.data : { *(.init.data) }
+	.init.data : {
+		*(.init.data)
+	}
 
 	. = ALIGN(16);
+	.init.setup : {
 		__setup_start = .;
-  .init.setup : { *(.init.setup) }
+		*(.init.setup)
 		__setup_end = .;
+	}
 
 	. = ALIGN(8);
-  __initcall_start = .;
 	.initcall.init : {
+		__initcall_start = .;
 		INITCALLS
-  }
 		__initcall_end = .;
+	}
 
 #ifdef CONFIG_BLK_DEV_INITRD
-  . = ALIGN(8192);
+	. = ALIGN(PAGE_SIZE);
+	.init.ramfs : {
 		__initramfs_start = .;
-  .init.ramfs : { *(.init.ramfs) }
+		*(.init.ramfs)
 		__initramfs_end = .;
+	}
 #endif
 
 	. = ALIGN(8);
@@ -73,73 +86,68 @@ SECTIONS
 	. = ALIGN(8);
 	SECURITY_INIT
 
-  PERCPU(8192)
+	PERCPU(PAGE_SIZE)
 
-  . = ALIGN(2*8192);
+	. = ALIGN(2 * PAGE_SIZE);
 	__init_end = .;
 	/* Freed after init ends here */
 
 	/* Note 2 page alignment above.  */
-  .data.init_thread : { *(.data.init_thread) }
+	.data.init_thread : {
+		*(.data.init_thread)
+	}
 
-  . = ALIGN(8192);
-  .data.page_aligned : { *(.data.page_aligned) }
+	. = ALIGN(PAGE_SIZE);
+	.data.page_aligned : {
+		*(.data.page_aligned)
+	}
 
 	. = ALIGN(64);
-  .data.cacheline_aligned : { *(.data.cacheline_aligned) }
+	.data.cacheline_aligned : {
+		*(.data.cacheline_aligned)
+	}
 
 	_data = .;
-  .data : {					/* Data */
+	/* Data */
+	.data : {
 		DATA_DATA
 		CONSTRUCTORS
 	}
 
-  .got : { *(.got) }
-  .sdata : { *(.sdata) }
-
+	.got : {
+		*(.got)
+	}
+	.sdata : {
+		*(.sdata)
+	}
 	_edata = .;	/* End of data section */
 
 	__bss_start = .;
-  .sbss : { *(.sbss) *(.scommon) }
-  .bss : { *(.bss) *(COMMON) }
+	.sbss : {
+		*(.sbss)
+		*(.scommon)
+	}
+	.bss : {
+		*(.bss)
+		*(COMMON)
+	}
 	__bss_stop = .;
-
 	_end = .;
 
 	/* Sections to be discarded */
-  /DISCARD/ : { *(.exit.text) *(.exit.data) *(.exitcall.exit) }
-
-  .mdebug 0 : { *(.mdebug) }
-  .note 0 : { *(.note) }
-  .comment 0 : { *(.comment) }
-
-  /* Stabs debugging sections */
-  .stab 0 : { *(.stab) }
-  .stabstr 0 : { *(.stabstr) }
-  .stab.excl 0 : { *(.stab.excl) }
-  .stab.exclstr 0 : { *(.stab.exclstr) }
-  .stab.index 0 : { *(.stab.index) }
-  .stab.indexstr 0 : { *(.stab.indexstr) }
-  /* DWARF 1 */
-  .debug          0 : { *(.debug) }
-  .line           0 : { *(.line) }
-  /* GNU DWARF 1 extensions */
-  .debug_srcinfo  0 : { *(.debug_srcinfo) }
-  .debug_sfnames  0 : { *(.debug_sfnames) }
-  /* DWARF 1.1 and DWARF 2 */
-  .debug_aranges  0 : { *(.debug_aranges) }
-  .debug_pubnames 0 : { *(.debug_pubnames) }
-  /* DWARF 2 */
-  .debug_info     0 : { *(.debug_info) }
-  .debug_abbrev   0 : { *(.debug_abbrev) }
-  .debug_line     0 : { *(.debug_line) }
-  .debug_frame    0 : { *(.debug_frame) }
-  .debug_str      0 : { *(.debug_str) }
-  .debug_loc      0 : { *(.debug_loc) }
-  .debug_macinfo  0 : { *(.debug_macinfo) }
-  /* SGI/MIPS DWARF 2 extensions */
-  .debug_weaknames 0 : { *(.debug_weaknames) }
-  .debug_funcnames 0 : { *(.debug_funcnames) }
-  .debug_typenames 0 : { *(.debug_typenames) }
-  .debug_varnames  0 : { *(.debug_varnames) }
+	/DISCARD/ : {
+		*(.exit.text)
+		*(.exit.data)
+		*(.exitcall.exit)
+	}
+
+	.mdebug 0 : {
+		*(.mdebug)
+	}
+	.note 0 : {
+		*(.note)
+	}
+
+	STABS_DEBUG
+	DWARF_DEBUG
 }

include/asm-alpha/page.h

@@ -3,11 +3,12 @@
 
 #ifdef __KERNEL__
 
+#include <linux/const.h>
 #include <asm/pal.h>
 
 /* PAGE_SHIFT determines the page size */
 #define PAGE_SHIFT	13
-#define PAGE_SIZE	(1UL << PAGE_SHIFT)
+#define PAGE_SIZE	(_AC(1,UL) << PAGE_SHIFT)
 #define PAGE_MASK	(~(PAGE_SIZE-1))
 
 #ifndef __ASSEMBLY__