uml: fix linker script alignment bugs

Fix a class of bugs in the UML linker scripts which caused section boundary
variables to sometimes not line up with their sections.
Signed-off-by: NJeff Dike <jdike@linux.intel.com>
Signed-off-by: NAndrew Morton <akpm@linux-foundation.org>
Signed-off-by: NLinus Torvalds <torvalds@linux-foundation.org>

arch/um/kernel/dyn.lds.S

@@ -71,11 +71,13 @@ SECTIONS
     *(.gnu.warning)
 
     . = ALIGN(4096);
+  } =0x90909090
+  . = ALIGN(4096);
+  .syscall_stub : {
 	__syscall_stub_start = .;
 	*(.__syscall_stub*)
 	__syscall_stub_end = .;
-    . = ALIGN(4096);
-  } =0x90909090
+  }
   .fini           : {
     KEEP (*(.fini))
   } =0x90909090
@@ -138,8 +140,8 @@ SECTIONS
   .got            : { *(.got.plt) *(.got) }
   _edata = .;
   PROVIDE (edata = .);
-  __bss_start = .;
   .bss            : {
+   __bss_start = .;
    *(.dynbss)
    *(.bss .bss.* .gnu.linkonce.b.*)
    *(COMMON)

arch/um/kernel/uml.lds.S

@@ -44,12 +44,13 @@ SECTIONS
     /* .gnu.warning sections are handled specially by elf32.em.  */
     *(.gnu.warning)
     *(.gnu.linkonce.t*)
+  }
 
   . = ALIGN(4096);
+  .syscall_stub : {
 	__syscall_stub_start = .;
 	*(.__syscall_stub*)
 	__syscall_stub_end = .;
-    . = ALIGN(4096);
   }
 
   #include "asm/common.lds.S"

include/asm-um/common.lds.S

@@ -16,82 +16,112 @@
 
   . = ALIGN(4096);
   .note : { *(.note.*) }
+  __ex_table : {
 	__start___ex_table = .;
-  __ex_table : { *(__ex_table) }
+	*(__ex_table)
 	__stop___ex_table = .;
+  }
 
   BUG_TABLE
 
+  .uml.setup.init : {
 	__uml_setup_start = .;
-  .uml.setup.init : { *(.uml.setup.init) }
+	*(.uml.setup.init)
 	__uml_setup_end = .;
+  }
 	
+  .uml.help.init : {
 	__uml_help_start = .;
-  .uml.help.init : { *(.uml.help.init) }
+	*(.uml.help.init)
 	__uml_help_end = .;
+  }
 	
+  .uml.postsetup.init : {
 	__uml_postsetup_start = .;
-  .uml.postsetup.init : { *(.uml.postsetup.init) }
+	*(.uml.postsetup.init)
 	__uml_postsetup_end = .;
+  }
 	
+  .init.setup : {
 	__setup_start = .;
-  .init.setup : { *(.init.setup) }
+	*(.init.setup)
 	__setup_end = .;
+  }
 
   . = ALIGN(32);
+  .data.percpu : {
 	__per_cpu_start = . ;
-  .data.percpu : { *(.data.percpu) }
+	*(.data.percpu)
 	__per_cpu_end = . ;
+  }
 	
-  __initcall_start = .;
   .initcall.init : {
+	__initcall_start = .;
 	INITCALLS
-  }
 	__initcall_end = .;
+  }
 
+  .con_initcall.init : {
 	__con_initcall_start = .;
-  .con_initcall.init : { *(.con_initcall.init) }
+	*(.con_initcall.init)
 	__con_initcall_end = .;
+  }
 
+  .uml.initcall.init : {
 	__uml_initcall_start = .;
-  .uml.initcall.init : { *(.uml.initcall.init) }
+	*(.uml.initcall.init)
 	__uml_initcall_end = .;
+  }
   __init_end = .;
 
   SECURITY_INIT
 
+  .exitcall : {
 	__exitcall_begin = .;
-  .exitcall : { *(.exitcall.exit) }
+	*(.exitcall.exit)
 	__exitcall_end = .;
+  }
 
+  .uml.exitcall : {
 	__uml_exitcall_begin = .;
-  .uml.exitcall : { *(.uml.exitcall.exit) }
+	*(.uml.exitcall.exit)
 	__uml_exitcall_end = .;
+  }
 
   . = ALIGN(4);
+  .altinstructions : {
 	__alt_instructions = .;
-  .altinstructions : { *(.altinstructions) }
+	*(.altinstructions)
 	__alt_instructions_end = .;
+  }
   .altinstr_replacement : { *(.altinstr_replacement) }
   /* .exit.text is discard at runtime, not link time, to deal with references
      from .altinstructions and .eh_frame */
   .exit.text : { *(.exit.text) }
   .exit.data : { *(.exit.data) }
 
+  .preinit_array : {
 	__preinit_array_start = .;
-  .preinit_array : { *(.preinit_array) }
+	*(.preinit_array)
 	__preinit_array_end = .;
+  }
+  .init_array : {
 	__init_array_start = .;
-  .init_array : { *(.init_array) }
+	*(.init_array)
 	__init_array_end = .;
+  }
+  .fini_array : {
 	__fini_array_start = .;
-  .fini_array : { *(.fini_array) }
+	*(.fini_array)
 	__fini_array_end = .;
+  }
 
    . = ALIGN(4096);
+  .init.ramfs : {
 	__initramfs_start = .;
-  .init.ramfs : { *(.init.ramfs) }
+	*(.init.ramfs)
 	__initramfs_end = .;
+  }
 
   /* Sections to be discarded */
   /DISCARD/ : {